interp

See Also  edit

island and firewall, by EF

A way to bring back some file access to safe interpreters, but only for some islands of the filesystem, or to let them access network resources, but only for some restricted hosts.

corp

Can be used to "ship" a procedure to another interpreter.

Dumping interpreter state

An attempt by RS to record the state of an interpreter.

fmail, by AK

Nicely employs slave interpreters.

exit in slave interpreter

Covers a specific trickiness in interp management.

Managing Complexity in TeamRooms, a Tcl-Based Internet Groupware Application, Mark Roseman, 1996

An article about TeamWave that explains specific interp benefits of encapsulation and security. In a conversation in mid-2001, Mark summarized, "But if you have what might be considered very coarse-grained objects that really could be conceptualized as self-contained applications, multiple Tcl interpreters are definitely an option to consider."

remote interpreter

Safe Interps

dgp: Nicely encapsulated the role of interp as to address "isolation and partition".

tkcon

An enhanced Tk console built in pure Tcl/Tk. It makes use of slave interpreters to isolate the user environment from the tkcon environment, except through certain special commands. It makes use of many tricks with interpreter slaves.

Windows focus and multiple proc, comp.lang.tcl, 2002-05-02

DKF illustrates that interps can serve as an elegant "light-weight" way to implement related proc-s in a unified fashion.

Syntax  edit

interp option ?arg arg ...?

interp alias srcPath srcToken

interp alias srcPath srcToken {}

interp alias srcPath srcToken targetPath targetCmd ?arg arg ...?

interp aliases ?path?

interp bgerror path ?cmdPrefix?

interp cancel ?-unwind? ?- -? ?path? ?result?

interp create ?-safe? ?- -? ?path?

interp debug path ?-frame ?boolean??

interp delete ?path ...?

interp eval path arg ?arg ...?

interp exists path

interp expose path hiddenName ?exposedCmdName?

interp hidden path

interp hide path exposedCmdName ?hiddenCmdName?

interp invokehidden path ?-option ...? hiddenCmdName ?arg ...?

interp issafe ?path?

interp limit path limittype ?-option? ?value ...?

interp marktrusted path

interp recursionlimit path ?newlimit?

interp share srcPath channelId destPath

interp slaves ?path?

interp target path alias

interp transfer srcPath channelId destPath

Documentation  edit

official reference

Description  edit

http://groups.google.com/groups?hl=en&frame=right&th=d0e2fc9300bdbad

Shared Resources  edit

Examples  edit

# Create a new interpreter named "a":
interp create a

# Create a new interpreter named "b" within interpreter "a":
interp create {a b}

# Create a new interpreter named "c" within interpreter "b":
interp create {a b c}

# Make the "c" interpreter do something:
interp eval {a b c} [list puts "Hello there."]

# This is another way to create a new interpreter
#   within an interpreter (named dionysus):
interp eval {a b c} [list interp create dionysus]

# Let's get "dionysus" to do something by invoking it by name. 
interp eval {a b c} \
 [list dionysus eval [list puts "Interpreter nesting works."]]

set mycommand {puts "Interpreter paths have *nothing* to do\
with the filesystem."}

interp eval {a b c dionysus} $mycommand

package require Tk
package require http
pack [frame .f -container true]
set i [interp create -safe]
::safe::loadTk $i -use [winfo id .f]
proc http_source {interp base filename} {
    regsub {.*:/*} $filename {} trimmed
    set token [http::geturl $base$trimmed]
    set script [http::data $token]
    http::cleanup $token
    $interp eval $script
}
$i alias source http_source $i $YourBaseUrl
$i expose exit;  # WE DON'T MIND PEOPLE QUITTING THE APP!
http_source $i $YourBaseUrl InitApp.tcl
vwait forever

% interp create foo
foo

Coupling variables between interpreters  edit

# shareVar.tcl --
#
#     Allow sharing (or linking) of variables between interpreters.
#
#
# Copyright 2002  Pinebush Technologies, Inc.
#
# Exported procs:
#     sharevar::sharevar - Sets up link between interpreters
#
# Private procs:
#     sharevar::TraceVariable - Updates other interpreter when
#                               variable is written.
#
# Example:
#     # Create a slave interpreter
#     interp create a
#
#     # Share a variable (common name)
#     sharevar::sharevar {} foo a foo
#
#     # Create a namespace to play with.
#     namespace eval X {
#         variable X
#     }
#
#     # Share a variable (different name and namespace).
#     sharevar::sharevar {} X::X a x
#
#     # Create another slave
#     interp create b
#
#     # Share a variable between them
#     sharevar::sharevar a a b b
#
#
# Global data:
#     None.
#
#-----------------------------------------------------------------------

package provide sharevar 0.1

namespace eval ::sharevar {
    namespace export \
            sharevar
}

#=======================================================================
# Public procs
#=======================================================================
# sharevar::sharevar --
#
#     Make varName a shared variable in sourcePath and targetPath.
# 
# Arguments:
#     sourcePath - First interpreter to link
#     sourceVar  - Variable in sourcePath to link to
#     targetPath - Second interpreter to link
#     targetVar  - Variable in targetPath to link to
#
# Results:
#     Updates to sourceVar in sourcePath will change targetVar in targetPath
#     and vice versa.
#
#     If sourceVar exists, targetVar is set to its value.  If sourceVar
#     does not exist, and targetVar does, sourceVar is set to
#     targetVar's value.
#
proc sharevar::sharevar { sourcePath sourceVar targetPath targetVar} {
    foreach fromInterp [list $sourcePath $targetPath] \
            fromVar    [list $sourceVar $targetVar] \
            toInterp   [list $targetPath $sourcePath] \
            toVar      [list $targetVar $sourceVar] \
            {

        # Give the interpreter the sharing proc
        interp alias $fromInterp shareTraceVariable \
                {} [namespace code TraceVariable]

        # Use that command when the variable is written.
        set traceCmd [list shareTraceVariable \
                $fromInterp $fromVar $toInterp $toVar]
        interp eval $fromInterp \
                [list trace variable ::$fromVar w $traceCmd]
        # WUZ - need to clean up later, remove trace

    }

    # Initial synchronization
    if { [interp eval $sourcePath info exists $sourceVar]} {
        TraceVariable $sourcePath $sourceVar $targetPath $targetVar
    } elseif { [interp eval $targetPath info exists $targetVar]
    && ! [interp eval $sourcePath info exists $sourceVar]} {
        TraceVariable  $targetPath $targetVar $sourcePath $sourceVar
    } else {
        # Neither exists, first write will sync.
    }

}
# sharevar::sharevar
#
#=======================================================================
# Private procs only below this line
#=======================================================================
# sharevar::TraceVariable --
#
#     React to change in one interpreter by updating the other.
# 
# Arguments:
#     fromInterp - Interpreter where value changed
#     fromVar    - Variable in fromInterp which changed
#     toInterp   - Interpreter to update
#     toVar      - Variable in toInterp to update
#     args       - (IGNORED) Added by the variable trace
#
# Results:
#     toVar is updated
#
proc sharevar::TraceVariable { fromInterp fromVar toInterp toVar args } {
    puts stderr [info level 0]
    set value [interp eval $fromInterp set ::$fromVar]
    interp eval $toInterp [list set ::$toVar $value]
}
# sharevar::TraceVariable

Discussion  edit

 suchenwi: Another OT: Why do windows have children, but interps have slaves?
 stever:   because slaves do work? children just play?

package require Tk
package require http
pack [frame .f -container true]
set i [interp create -safe]
::safe::loadTk $i -use [winfo id .f]
...and the remainder of the script...

can't read "Sinterp0(access_path,n)": no such element in array
   while executing

interp create slave
load {} Tk slave

interp eval slave package require Tk

Thread 0 Crashed:: Dispatch queue: com.apple.main-thread
0   libsystem_kernel.dylib                0x93f9b9c6 __pthread_kill + 10
1   libsystem_c.dylib                     0x93781f78 pthread_kill + 106
2   libsystem_c.dylib                     0x93772bdd abort + 167
3   Tcl                                   0x001d8e77 Tcl_PanicVA + 227
4   Tcl                                   0x001d8e92 Tcl_Panic + 27
5   Tcl                                   0x001bf518 Tcl_RegisterChannel + 108
6   Tk                                    0x0e66fed8 TkpInit + 1207
...

• Home
• Recent changes
• Help
• WhoAmI/Logout
• Create new page
• Random page
• Previous page
• Next page
• 
  
• Add comments
• Edit
• History
• Edit summary
• References